## 呼吸灯

本节，我们将通过脉宽调制技术来实现“呼吸灯”，实现LED的亮度由最暗逐渐增加到最亮，再逐渐变暗的过程。
脉冲宽度调制(PWM:Pulse Width Modulation)，简称脉宽调制。它是利用微控制器的数字输出调制实现，是对模拟电路进行控制的一种非常有效的技术，广泛应用于测量、通信、功率控制与变换等众多领域。
\\
### 硬件说明

呼吸灯的设计较为简单，我们使用12MHz的系统时钟作为高频信号做分频处理，调整占空比实现PWM，通过LED灯LD1指示输出状态。

{{ :led电路连接.jpg |LED电路连接}}

{{ :脉冲有效值.jpg |脉冲信号有效值}}

实现原理如上图所示，脉冲信号的周期为T，高电平脉冲宽度为t，占空比为t/T。为了实现PWM脉宽调制，我们需要保持周期T不变，调整高电平脉宽t的时间，从而改变占空比。

  * 当t = 0时，占空比为0%，因为我们的LED硬件为低电平点亮，所以为最亮的状态。
  * 当t = T时，占空比为100%，LED灯为最暗（熄灭）的状态。

结合呼吸灯的原理，整个呼吸的周期为最亮→最暗→最亮的时间，即t的值的变化：0→T→0逐渐变化，这个时间应该为2s
{{ :呼吸灯程序设计.jpg |呼吸灯程序设计}}

呼吸灯设计要求呼吸的周期为2s，也就是说LED灯从最亮的状态开始，第一秒时间内逐渐变暗，第二秒的时间内再逐渐变亮，依次进行。

本设计中需要两个计数器cnt1和cnt2，cnt1随系统时钟同步计数（系统时钟上升沿时cnt1自加1）范围为0~T，cnt2随cnt1的周期同步计数（cnt1等于T时，cnt2自加1）范围也是0~T，这样每次cnt1在0~T的计数时，cnt2为一个固定值，相邻cnt1计数周期对应的cnt2的值逐渐增大，我们将cnt1计数0~T的时间作为脉冲周期，cnt2的值作为脉冲宽度，则占空比 = cnt2/T,占空比从0%到100%的时间 = cnt2*cnt1 = T^2 = 1s = 12M个系统时钟，T = 2400，我们定义CNT_NUM = 2400作为两个计数器的计数最大值。

{{ ::呼吸灯pwm原理.jpg |PWM呼吸灯原理}}

### Verilog代码
<code verilog>

// ********************************************************************
// >>>>>>>>>>>>>>>>>>>>>>>>> COPYRIGHT NOTICE <<<<<<<<<<<<<<<<<<<<<<<<<
// ********************************************************************
// File name    : breath_led.v
// Module name  : breath_led
// Author       : STEP
// Description  : 
// Web          : www.stepfpga.com
// 
// --------------------------------------------------------------------
// Code Revision History : 
// --------------------------------------------------------------------
// Version: |Mod. Date:   |Changes Made:
// V1.0     |2017/03/02   |Initial ver
// --------------------------------------------------------------------
// Module Function:呼吸灯
module breath_led(clk,rst,led);
	
	input clk;             //系统时钟输入
	input rst;             //复位输出
	output led;            //led输出
	
	reg [24:0] cnt1;       //计数器1
	reg [24:0] cnt2;       //计数器2
	reg flag;              //呼吸灯变亮和变暗的标志位
	
	//parameter   CNT_NUM = 2400;	//计数器的最大值 period = (2400^2)*2 ~= 12000000 = 1s由亮到暗0.5s，由暗到亮0.5s
	parameter   CNT_NUM = 3464;	//计数器的最大值 period = (3464^2)*2 ~= 24000000 = 2s由亮到暗1s，由暗到亮1s
	//产生计数器cnt1
	always@(posedge clk or negedge rst) begin 
		if(!rst) begin
			cnt1<=13'd0;
			end 
                else begin
		     if(cnt1>=CNT_NUM-1) 
                        cnt1<=1'b0;
		     else 
                        cnt1<=cnt1+1'b1; 
                    end
		end

	//产生计数器cnt2
	always@(posedge clk or negedge rst) begin 
		if(!rst) begin
			cnt2<=13'd0;
			flag<=1'b0;
			end 
                else begin
		     if(cnt1==CNT_NUM-1) begin              //当计数器1计满时计数器2开始计数加一或减一
			if(!flag) begin                     //当标志位为0时计数器2递增计数，表示呼吸灯效果由暗变亮
				if(cnt2>=CNT_NUM-1)         //计数器2计满时，表示亮度已最大，标志位变高，之后计数器2开始递减
                                    flag<=1'b1;
				else
                                    cnt2<=cnt2+1'b1;
			end else begin                     //当标志位为高时计数器2递减计数
				if(cnt2<=0)                //计数器2级到0，表示亮度已最小，标志位变低，之后计数器2开始递增
                                    flag<=1'b0;
				else 
                                    cnt2<=cnt2-1'b1;
			end
			end
                            else cnt2<=cnt2;              //计数器1在计数过程中计数器2保持不变
			end
			end

	//比较计数器1和计数器2的值产生自动调整占空比输出的信号，输出到led产生呼吸灯效果
	assign	led = (cnt1<cnt2)?1'b0:1'b1;

endmodule 


</code>

### 引脚分配

引脚分配如下：

^ 管脚名称 |  clk  |  rst  |  led  |
^ FPGA管脚 |  J5    |  J9  |  N15       |


### 小结

脉宽调制是一种值得广大工程师在许多应用设计中使用的有效技术，你也可以根据本节介绍的流水灯程序，实现RGB三色灯的呼吸。在下一小节我们会学习状态机的使用方法：[[altera_10tra|交通灯的设计]]。